set term pdf font 'helvetica,16' size 5,4 dashed
set output 'thin_stress_tresca.pdf'
set samples 1000

# Define constants
sigma_0 = 1000.
rho = 8.08e-9
omega = 10000. # rad/s
nu = 0.3
r_i = 5.
a = 14.
r_e = 50.

print (omega**2)

# Define equations for A, B, and C
A = -sigma_0/2.*a*r_i + rho*omega**2*a**4/6.*(-(1+3*nu)/4.+(r_i/a)**3)
B = sigma_0*(1-r_i/2./a) + rho*omega**2*a**2/6.*((1+3*nu)/2.+(r_i/a)**3)
C = -r_i*(log(a/r_e)+nu)*(rho*omega**2*r_i**2/3.-sigma_0) + rho*omega**2*a**3/9.*(1+3*nu)

# Define equations for radial and tangential stresses
sigma_rr(r) = (r_i <= r && r <= a) ? sigma_0*(1-r_i/r) - rho*omega**2*r**2/3.*(1-(r_i/r)**3) : -rho*omega**2*r**2/8.*(3+nu) + A/r**2 + B
sigma_tt(r) = (r_i <= r && r <= a) ? sigma_0 : -rho*omega**2*r**2/8.*(1+3*nu) - A/r**2 + B
sigma_zz(r) = (r_i <= r && r <= a) ? 0. : 0. 

# Set plot parameters
set xlabel 'r/r_i'
set ylabel 'Stress [MPa]'
set xrange [r_i/r_e:1.]
set yrange [0:1.2*sigma_0]

# Plot radial and tangential stresses
r_norm(x)=x*r_e
plot sigma_rr(r_norm(x)) with lines lw 3. dt 1 title 'radial stress {/Symbol s}_{rr}', \
     sigma_tt(r_norm(x)) with lines lw 3. dt 4 title 'tangential stress {/Symbol s}_{{/Symbol t}{/Symbol t}}',\
     sigma_zz(r_norm(x)) with lines lw 3. dt 4 title '{/Symbol s}_{zz}',\
     'thin_stress_tresca.dat' u ($1/r_e):2 with points lc rgb "black" lw 0.5 ps 0.5 pt 4 notitle,\
     'thin_stress_tresca.dat' u ($1/r_e):4 with points lc rgb "black" lw 0.5 ps 0.5 pt 8 notitle,\
     'thin_stress_tresca.dat' u ($1/r_e):3 with points lc rgb "black" lw 0.5 ps 0.5 pt 6 notitle

# Save and close plot
unset output

set output 'thin_stress_mises.pdf'

plot 'thin_stress_mises.dat' u ($1/r_e):2 with points lc rgb "black" lw 1. ps 0.5 pt 4 title 'radial stress {/Symbol s}_{rr}',\
     'thin_stress_mises.dat' u ($1/r_e):4 with points lc rgb "black" lw 1. ps 0.5 pt 8 title 'tangential stress {/Symbol s}_{{/Symbol t}{/Symbol t}}',\
     'thin_stress_mises.dat' u ($1/r_e):3 with points lc rgb "black" lw 1. ps 0.5 pt 6 title '{/Symbol s}_{zz}'

unset output